# Contributor: Camille <onodera@rizon>
# Maintainer: aksr <aksr at t-com dot me>
pkgname=wmutils-git
pkgver=1.0.r25.g7b86e8b
pkgrel=1
pkgdesc="A set of tools for X windows manipulation."
url="https://github.com/wmutils/core"
arch=('i686' 'x86_64')
license=('ISC')
depends=('libxcb')
source=('git+https://github.com/wmutils/core.git'
	'git+https://github.com/wmutils/opt.git'
	'git+https://github.com/wmutils/contrib.git')
sha1sums=('SKIP'
          'SKIP'
          'SKIP')

pkgver() {
  cd core
  git describe --long --tags | sed -r 's/([^-]*-g)/r\1/;s/-/./g;s/^v//g'
}

build() {
  cd "$srcdir"/core
  make

  cd "$srcdir"/opt
  make

  cd "$srcdir"/contrib/killwa
  make
}

package() {
  cd "$srcdir"/core
  make DESTDIR="$pkgdir" PREFIX=/usr install

  cd "$srcdir"/opt
  make DESTDIR="$pkgdir" PREFIX=/usr install

  cd "$srcdir"/contrib
  install -d "$pkgdir"/usr/share/wmutils/examples
  install -m644 *.sh "$pkgdir"/usr/share/wmutils/examples

  cd killwa
  install -m755 killwa "$pkgdir"/usr/bin
}